// textures03.pov
// POV-Ray 3.5 scene file by En-Chong Pak
// The initial appearance of a glass sphere before modifying transparency.
// Render in 240x180, antialiasing 0.3, method 2.

#include "colors.inc"
#include "textures.inc"

#declare Photons=on;

global_settings {
   assumed_gamma 1.0
   max_trace_level 5
   #if (Photons)        // global photon block
      photons {
         spacing 0.02   // specify the density of photons
      }
   #end

}

camera {
   location <-1.6, 3.0, -4.0>
   direction 1.5*z
   right x*image_width/image_height
   look_at <0.0, 0.0, 0.0>
}

sky_sphere {
   pigment {
      gradient y
      color_map {
         [0.0 rgb <1.0, 1.0, 1.0>]
         [0.7 rgb <0.6, 0.7, 1.0>]
      }
   }
}

light_source {
   <0.0, 0.0, 0.0>            // light's position (translated below)
   color rgb <1.0, 1.0, 1.0>  // light's color
   translate <-50.0, 50.0, 10.0>
   photons {         // photon block for a light source
      refraction on
      reflection on
   }
}

plane {               // checkered floor
   y, -1
   texture {
      pigment {
         checker
         color rgb 1.0
         color Gray50
         scale 0.5
      }
      finish {
         diffuse 0.8
         ambient 0.1
         reflection 0.3
      }
   }
}

box {                // cartesian y-axis
   <-0.05, -0.01, -6.0>, <0.05, 0.01, 6.0>
   texture {
      pigment {
         color Black
      }
      finish {
         diffuse 0.3
         ambient 0.3
         specular 0.6
         reflection 0.3
      }
   }
   translate <-1.05, -0.99, 4.5>
}

box {                // cartesian x-axis
   <-0.05, -0.01, -6.0>, <0.05, 0.01, 6.0>
   texture {
      pigment {
         color Black
      }
      finish {
         diffuse 0.3
         ambient 0.3
         specular 0.6
         reflection 0.3
      }
   }
   translate <1.05, -0.99, 3.5>
   rotate <0.0, 90.0, 0.0>
}

sphere {              // glass sphere
   0.0, 1
   texture {
      pigment {
         color White transmit 1.0
      }
      finish {
         diffuse 0.05
         ambient 0.0
         specular 0.8
         reflection {
           0.1, 1.0
           fresnel on
         }
         conserve_energy
      }
   }
   interior {
      ior 1.5        // index of refraction for glass
   }
   photons {         // photon block for an object
      target 1.0
      refraction on
      reflection on
   }
}